**Next message:**Vladyslav Shtabovenko: "Re: ??"**Previous message:**Vladyslav Shtabovenko: "Re: ?"**In reply to:**Vladyslav Shtabovenko: "Re: ?"**Next in thread:**Vladyslav Shtabovenko: "Re: ??"**Reply:**Vladyslav Shtabovenko: "Re: ??"**Messages sorted by:**[ date ] [ thread ] [ subject ] [ author ]**Mail actions:**[ respond to this message ] [ mail a new topic ]

Hi, Vladyslave:

Please see the attached letter and .nb file. JP

HSU Jongping,

Chancellor Professor

Department of Physics

Univ. of Massachusetts Dartmouth,

North Dartmouth, MA 02747. FAX (508)999-9115

http://www.umassd.edu/engineering/phy/people/facultyandstaff/jong-pinghsu/

recent monograph: Space-Time Symmetry and Quantum Yangâ€“Mills Gravity (https://sites.google.com/site/yangmillsgravity123/)

----- Original Message -----

From: "Vladyslav Shtabovenko" <dev@shtabovenko.df-kunde.de>

To: feyncalc@feyncalc.org

Sent: Monday, November 14, 2016 4:48:03 PM

Subject: Re: ?

Good evening (according to Munich time),

Rolf "delegated" the development of FeynCalc to me since some time,

so he is now more acting as a supervisor, while I do the coding.

First of all let me remark, that the amplitude for the first diagram

does not look correct to me. I can only guess, what routing of momenta

was meant here, but assuming that it is

mu

/|\ /|~~~~~~~~ -> p

q | / |

| / | /|\

~~~~~~~~~~/ | | p-q

| \la | |

| \ |

-q \|/ \ |

\|~~~~~~~~ -> -p

nu

the amplitude should be written as

g1 = GluonGhostVertex[{0, la, a}, {q, la1, a1}, {-q, la2, a2}] //

Explicit;

g2 = GluonGhostVertex[{p, mu, b}, {-q, mu1, b1}, {q - p, mu2, b2}] //

Explicit;

g3 = GluonGhostVertex[{-p, nu, c}, {p - q, nu1, c1}, {q, nu2, c2}] //

Explicit

gp = g1*g2*g3 // Contract // Explicit // Simplify

g12 = GhostPropagator[q, a1, b2] // Explicit

g23 = GhostPropagator[p - q, b1, c2] // Explicit;

g31 = GhostPropagator[q, c1, a2] // Explicit;

gpro = g12*g23*g31 // FeynAmpDenominatorCombine;

tp = gpro*gp // Contract // SUNSimplify // Simplify

i.e. in my view g2 and g3t in the attached notebook need to be corrected.

One can check this explicitly by comparing to the FeynArts output (

on a new kernel):

$LoadFeynArts = True;

<< FeynCalc`

$FAVerbose = False;

top = CreateTopologies[1, 1 -> 2,

ExcludeTopologies -> {WFCorrections, SelfEnergies, Tadpoles}];

diags = InsertFields[top, {V[5]} -> {V[5], V[5]}, Model -> "SMQCD",

InsertionLevel -> {Particles},

ExcludeParticles -> {F[__], S[_], V[_], U[1 | 2 | 3 | 4]}];

Paint[diags, ColumnsXRows -> {2, 1}, SheetHeader -> False,

SheetHeader -> None, Numbering -> None, ImageSize -> {512, 256}];

amps = FCFAConvert[

CreateFeynAmp[diags, Truncated -> True, GaugeRules -> {},

PreFactor -> 1], IncomingMomenta -> {p1},

OutgoingMomenta -> {p2, p3}, LoopMomenta -> {q},

DropSumOver -> True, UndoChiralSplittings -> True,

ChangeDimension -> D, List -> True, SMP -> True,

LorentzIndexNames -> {\[Lambda], \[Mu], \[Nu]}] // Contract //

SUNSimplify

amps[[2]] /. p3 -> -p2 /. p2 -> p

Notice that here the prefactor 1/(2Pi)^D is understood but not written

down explicitly.

My second remark is that the replacement D->4 should not be done when

the result contains Passarino-Veltman function multiplied by polynomials

in D. As PaVe funtions have poles in 1/Eps, taking the limit naively by just

putting D=4 leads to the wrong finite part in the final result.

As to the correctness of the result for the 3-gluon vertex, I currently

do not have a source the values of for both pieces separately at hand.

However, I believe that the result returned by FeynCalc is correct,

including the overall prefactor. A simple way to check it, is to look at

the UV-part of the ghost triangle, which can be found e.g. in Pascual

and Tarrach, QCD: Renormalization for Practitioner, Eq III.45

The 3-gluon vertex function (with all momenta ingoing) can be

parametrized as

"diagram" = i g T^{mu nu si}_{a b c}

with

T^{mu nu si}_{a b c} = - i f_abc (g^{mu nu} (p-q)^si + g^{nu si} (q-k)^mu +

g^{nu si} (q-k)^mu (k-p)^nu ) T1(p^2,q^2,k^2)

According to Pascual and Tarrach the UV part of T1(p^2,q^2,k^2) is given by

g^2/(4 Pi)^2 CA/8 1/(3 Eps)

By making the momenta p2 and p3 of the FeynArts amplitude ingoing

amps2 = (amps /. {p2 -> -p2, p3 -> -p3});

doing the tensor decomposition

ampsPT = (TID[#, q, ToPaVe -> True, UsePaVeBasis -> True] & /@ amps2);

and extracting the UV parts of the PaVe functions (c.f.

arXiv:hep-ph/0609282 for tabulated results)

uvParts = {PaVe[

1, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[2, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[0, 0, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 1/(64 EpsilonUV \[Pi]^4),

PaVe[1, 1, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[1, 2, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[2, 2, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[0, 0,

1, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> -(1/(192 EpsilonUV \[Pi]^4)),

PaVe[0, 0,

2, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> -(1/(192 EpsilonUV \[Pi]^4)),

PaVe[1, 1,

1, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[1, 1,

2, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[1, 2,

2, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0,

PaVe[2, 2,

2, {SPD[p2, p2], SPD[p2, p2] + 2 SPD[p2, p3] + SPD[p3, p3],

SPD[p3, p3]}, {0, 0, 0}, PaVeAutoOrder -> True,

PaVeAutoReduce -> True] -> 0};

ampsPT2 = ampsPT /. FCI[uvParts]

ampsPTUVpart1 = Total[ampsPT2] // FCE // Collect2[#, {Epsilon, MTD}] &

we obtain

-((CA (2 FVD[p2, \[Nu]] + FVD[p3, \[Nu]]) MTD[\[Lambda], \[Mu]] SMP[

"g_s"]^3 SUNF[a, b, c])/(384 EpsilonUV \[Pi]^2)) + (

CA (FVD[p2, \[Mu]] + 2 FVD[p3, \[Mu]]) MTD[\[Lambda], \[Nu]] SMP[

"g_s"]^3 SUNF[a, b, c])/(384 EpsilonUV \[Pi]^2) + (

CA (FVD[p2, \[Lambda]] - FVD[p3, \[Lambda]]) MTD[\[Mu], \[Nu]] SMP[

"g_s"]^3 SUNF[a, b, c])/(384 EpsilonUV \[Pi]^2)

this can be further simplified by exploiting the kinematics p1+p2+p3 = 0

ampsPTUVpart2 =

ampsPTUVpart1 /. {FVD[p2, i_] + 2 FVD[p3, i_] :>

FVD[p3, i] - FVD[p1, i],

FVD[p3, i_] + 2 FVD[p2, i_] :> FVD[p2, i] - FVD[p1, i]}

The Lorentz structure of the vertex function from Pascual and Tarrach is

given by

PTVertexFuLorentzStruct[{p_, q_, k_}, {mu_, nu_, si_}, {a_, b_,

c_}] :=

-I SUNF[a, b,

c] (MTD[mu, nu] FVD[p - q, si] + MTD[nu, si] FVD[q - k, mu] +

MTD[si, mu] FVD[k - p, nu])

so the UV part of T1(p^2,q^2,k^2) reads

Cancel[FCI[ExpandScalarProduct[ampsPTUVpart2]]/

ExpandScalarProduct[

FCI[PTVertexFuLorentzStruct[{p1, p2,

p3}, {\[Lambda], \[Mu], \[Nu]}, {a, b, c}]]]] // Simplify

res = %/(I SMP["g_s"])

comparing this to the result from the book we see the full agreement

PTGhostTriangleResult = SMP["g_s"]^2/(4 Pi)^2 CA/8 1/(3 EpsilonUV)

res - PTGhostTriangleResult

(* gives 0*)

So everything should be correct. I hope this helps to clarify the

discrepancy.

Cheers,

Vladyslav

Am 14.11.2016 um 03:20 schrieb Jongping Hsu:

*> Dear Dr. Mertig:
*

*> Could you please help to resolve a puzzling result that the OneLoop
*

*> FeynCalc calculation leads to incorrect results (in comparison with my
*

*> hand-calculations and those in the literature (e.g.,Politzer's) for the
*

*> 3rd. order Feynman diagram involving 3 ghost propagators and 3 external
*

*> gluon lines [with one external gluon momentum set to be zero for
*

*> simplicity] in the calculation of the asymptotic freedom)? Thank you
*

*> very much for your help.
*

*>
*

*> I used Mathematica 11 for calculations(with SU(2) in mind). My short
*

*> program is attached for your reference.
*

*>
*

*> Comments (do not run the .nb before reading these comments):
*

*>
*

*> 1. The vertices g1*g2*g3 contains 2 terms. For clarity, I first
*

*> calculate the first term by using the vertex g1*g2*g3t. The OneLoop[...]
*

*> gives the result A1, which is only half of the correct result A10 (see
*

*> In[2182]).
*

*> 2. I calculate the second term by using g1*g2*g3tt, which lead to the
*

*> oneloop result A2. Only when it is multiplied by(3/2), one gets the
*

*> correct result. See In[2198].
*

*> 3. In[2198]: By observation, A1*(4/2)+A2*(3/2) give the correct result.
*

*> 4. For the crossed diagram (of external gluons with non-zero momenta), a
*

*> similar corrections for the one-loop results (T1 and T) are done for the
*

*> 2 terms: B1=2*T1, B2=(3/2)*T.
*

*> 5. The corrected result, {A1*2 + A2*(3/2)}+{2*T1 + (3/2)*T}, leads to
*

*> the correct structure and magnitude of the diagram involving 3 ghost
*

*> internal lines, as shown in the coefficient of B0 in Out[2231] and in
*

*> Out[2232].
*

*>
*

*> HSU Jongping,
*

*> Chancellor Professor
*

*> Department of Physics
*

*> Univ. of Massachusetts Dartmouth,
*

*> North Dartmouth, MA 02747. FAX (508)999-9115
*

*> http://www.umassd.edu/engineering/phy/people/facultyandstaff/jong-pinghsu/
*

*> recent monograph: Space-Time Symmetry and Quantum Yangâ€“Mills Gravity
*

*> (https://sites.google.com/site/yangmillsgravity123/)
*

*>
*

- application/mathematica attachment: Gletter.nb

- application/mathematica attachment: GhostTriangle3ttt.nb

**Next message:**Vladyslav Shtabovenko: "Re: ??"**Previous message:**Vladyslav Shtabovenko: "Re: ?"**In reply to:**Vladyslav Shtabovenko: "Re: ?"**Next in thread:**Vladyslav Shtabovenko: "Re: ??"**Reply:**Vladyslav Shtabovenko: "Re: ??"**Messages sorted by:**[ date ] [ thread ] [ subject ] [ author ]**Mail actions:**[ respond to this message ] [ mail a new topic ]

*
This archive was generated by hypermail 2b29
: 05/27/18-09:40:01 PM Z CEST
*