**Next message:**Nikita Belyaev: "Re: Problem with the imaginary parts of the traces"**Previous message:**Nikita Belyaev: "Problem with the imaginary parts of the traces"**In reply to:**Nikita Belyaev: "Problem with the imaginary parts of the traces"**Next in thread:**Nikita Belyaev: "Re: Problem with the imaginary parts of the traces"**Messages sorted by:**[ date ] [ thread ] [ subject ] [ author ]**Mail actions:**[ respond to this message ] [ mail a new topic ]

Hi Nikita,

actually both results that you get are the same, but is a bit tricky to

see this. So let me explain.

Observe that a totally antisymmetric tensor with 5 indices is zero in

Minkowski space, where each index runs only from 0 to 3. This is

obvious, since with this setup you will always have two indices with the

same value between 0 and 3 such that the tensor will vanish by symmetry.

One can define such a tensor as

T^{mu,nu,rho,si,tau} =

eps^{mu,nu,rho,si} p^tau +

eps^{nu,rho,si,tau} p^mu +

eps^{rho,si,tau,mu} p^nu +

eps^{si,tau,mu,nu} p^rho +

eps^{tau,mu,nu,rho} p^si

We can also of course check explicitly that this tensor is totally

antisymmetric in all 5 indices. For example, for mu<->nu or rho<->tau

a1 = ((LC[mu, nu, rho, si] FV[p, tau] + LC[nu, rho, si, tau] FV[p, mu] +

LC[rho, si, tau, mu] FV[p, nu] + LC[si, tau, mu, nu] FV[p, rho] +

LC[tau, mu, nu, rho] FV[p, si]))

((a1 + (a1 /. {nu -> nu1, mu -> nu} /. {nu1 -> mu})) // Contract) === 0

((a1 + (a1 /. {rho -> rho1, tau -> rho} /. {rho1 -> tau})) // Contract )

=== 0

Hence, we conclude that

eps^{mu,nu,rho,si} p^tau + eps^{nu,rho,si,tau} p^mu +

eps^{rho,si,tau,mu} p^nu + eps^{si,tau,mu,nu} p^rho +

eps^{tau,mu,nu,rho} p^si = 0

which is the so called "Schouten identity". By using that

p^x = g^{x,ka} p_ka, i.e.

a2 = (a1 /. {FV[p, x_] :> MT[x, ka] FV[p, ka]}) // Factor

we can rewrite our identity as p^ka (.....) = 0 and get rid

of the p vector such that now we have

eps^{mu,nu,rho,si} g^{ka,tau} +

eps^{nu,rho,si,tau} g^{ka,mu} +

eps^{rho,si,tau,mu} g^{ka,nu} +

eps^{si,tau,mu,nu} g^{ka,rho} +

eps^{tau,mu,nu,rho} g^{ka,si} = 0

This relation looks somewhat weird, but nevertheless it is valid, since

we've just derived it.

Now observe that by multiplying it with some arbitrary LeviCivita tensor

it can get much more complicated, e.g.

a3 = a2 /. FV[__] :> 1)

a3 LC[i1, i2, i3, i4] // Contract

Here you get 120 terms with each term being a product of 5 metric

tensors. And yet you know that this huge sum of terms is zero, by the

Schouten identity!

In practice, this means that two expressions that look very different,

might indeed be the same by the virtue of the Schouten identity.

However, I'm not aware of any well-defined algorithm that can show such

equivalence. For simple cases one can usually figure out how to apply

Schouten identity just by looking at the form of the expression, but for

very large expressions this becomes very difficult.

Here

<http://www.nikhef.nl/~form/maindir/documentation/trace4>

is a nice write-up about that by Vermaseren, the author of FORM.

For some reason Schouten's identity is often omitted in QFT books and

lectures such that there are probably many particle physicists who have

never heard of it.

It is also the reason, why Dirac traces of the same expression computed

in different programs( e.g. FORM, FeynCalc and GiNaC) may look very

different and contain a different number of terms, although actually

they are identical.

In FeynCalc there is the function Schouten, that applies this identity

once and can thus show the equivalence for simple expressions.

Luckily, in you case it is sufficient:

ScalarProduct[p, p] = m^2;

ScalarProduct[p1, p1] = m^2;

ScalarProduct[p2, p2] = m^2;

ScalarProduct[k1, k1] = 0;

ScalarProduct[k2, k2] = 0;

ScalarProduct[q, q] = u^2;

ScalarProduct[q, s] = 0;

Line1 := 4*m*m* u*(GA[\[Beta]].GS[p2].GS[k1].GS[p1] -

m*m*GA[\[Beta]].GS[k1]);

Line2a := (-GS[q].GS[s].GA[\[Beta]] +

GS[s].GA[\[Beta]].(GS[q] - GS[p1] - GS[p2]) +

GA[\[Beta]].GS[q].GS[

s] + (GS[q] - GS[p1] - GS[p2]).GA[\[Beta]].GS[s]).GS[

k2].(1 - GA[5]);

Line2b := (GS[s].GS[q].GA[\[Beta]] +

GS[s].GA[\[Beta]].(GS[q] - GS[p1] - GS[p2]) +

GA[\[Beta]].GS[q].GS[

s] + (GS[q] - GS[p1] - GS[p2]).GA[\[Beta]].GS[s]).GS[

k2].(1 - GA[5]);

Tr1 = DiracTrace[Line1];

Tr2a = DiracTrace[Line2a];

Tr2b = DiracTrace[Line2b];

TrA1A2mod4a = FeynCalcFormLink[4*Tr1.Tr2a];

TrA1A2mod4b = FeynCalcFormLink[4*Tr1.Tr2b];

TrA1A2mod4a===TrA1A2mod4b

(TrA1A2mod4a - TrA1A2mod4b) // Schouten

Hence, as I wrote at the beginning, the two expressions are the same.

Cheers,

Vladyslav

On 13/03/15 00:57, Nikita Belyaev wrote:

*> Good night,
*

*>
*

*> Some time ago I've noticed a problem with the imaginary parts of the traces. You can see the example below:
*

*>
*

*> //----------------------------------------------------------------\\
*

*> Clear["Global`*"];
*

*> (*<<C:\Users\1\AppData\Roaming\Mathematica\Applications\FeynArts-3.9\FeynArts39.m*)
*

*> <<HighEnergyPhysics`FeynCalc`
*

*> (*{Date[],$Version,$FeynCalcVersion};*)
*

*> Needs["FeynCalcFormLink`"]
*

*> $LeviCivitaSign = -1;
*

*>
*

*> ScalarProduct[p,p] = m^2;
*

*> ScalarProduct[p1,p1] = m^2;
*

*> ScalarProduct[p2,p2] = m^2;
*

*> ScalarProduct[k1,k1] = 0;
*

*> ScalarProduct[k2,k2] = 0;
*

*> ScalarProduct[q,q] = u^2;
*

*> ScalarProduct[q,s] = 0;
*

*>
*

*> Line1:= 4*m*m*u*(GA[\[Beta]].GS[p2].GS[k1].GS[p1]-m*m*GA[\[Beta]].GS[k1]);
*

*> Line2:= (-GS[q].GS[s].GA[\[Beta]]+GS[s].GA[\[Beta]].(GS[q]-GS[p1]-GS[p2])+GA[\[Beta]].GS[q].GS[s]+(GS[q]-GS[p1]-GS[p2]).GA[\[Beta]].GS[s]).GS[k2].(1-GA[5]);
*

*>
*

*> Tr1= DiracTrace[Line1];
*

*> Tr2= DiracTrace[Line2];
*

*>
*

*> TrA1A2mod4=FeynCalcFormLink[4*Tr1.Tr2];
*

*>
*

*> Print["\!\(\*FractionBox[\(A1A2mod4\), \(1024\)]\)"]
*

*> FullSimplify[TrA1A2mod4/1024]
*

*> //----------------------------------------------------------------\\
*

*>
*

*> The result of such calculation is:
*

*> A1A2mod4/1024 = 1/8 m^2 u (k1\[CenterDot]s (4 (k2\[CenterDot]p1+k2\[CenterDot]p2) (m^2+p1\[CenterDot]p2)-I \[Epsilon]^(k2p1p2q))+k1\[CenterDot]q (-8 k2\[CenterDot]s (m^2+p1\[CenterDot]p2)-I \[Epsilon]^(k2p1p2s))+4 p1\[CenterDot]s (k1\[CenterDot]p1 k2\[CenterDot]p2-m^2 k1\[CenterDot]k2)-4 m^2 k1\[CenterDot]k2 p2\[CenterDot]s+I k2\[CenterDot]q \[Epsilon]^(k1p1p2s)+I k2\[CenterDot]s \[Epsilon]^(k1p1p2q)-I p1\[CenterDot]q \[Epsilon]^(k1k2p2s)-I p1\[CenterDot]s \[Epsilon]^(k1k2p2q)+I p2\[CenterDot]q \[Epsilon]^(k1k2p1s)+I p2\[CenterDot]s \[Epsilon]^(k1k2p1q)+8 k1\[CenterDot]p2 k2\[CenterDot]s p1\[CenterDot]q+8 k1\[CenterDot]p1 k2\[CenterDot]s p2\[CenterDot]q-4 k1\[CenterDot]p2 k2\[CenterDot]p2 p1\[CenterDot]s-4 k1\[CenterDot]k2 p1\[CenterDot]p2 p1\[CenterDot]s-4 k1\[CenterDot]p1 k2\[CenterDot]p1 p2\[CenterDot]s+4 k1\[CenterDot]p2 k2\[CenterDot]p1 p2\[CenterDot]s-4 k1\[CenterDot]k2 p1\[CenterDot]p2 p2\[CenterDot]s)
*

*>
*

*> It contains imaginary parts proportional to symmetric tensors like (s_{a}q_{b}+s_{b}q_{a}) and so on. So the imaginary parts of these traces is non-zero.
*

*>
*

*> But if we replace "Line2:= (-GS[q].GS[s]..." with "Line2:= (GS[s].GS[q]..." (GS[q].GS[s]+GS[s].GS[q]=0, because ScalarProduct[q,s] is also 0) we'll get the real result without any imaginary parts:
*

*> A1A2mod4/1024 = 1/2 m^2 u (-2 k1\[CenterDot]q k2\[CenterDot]s (m^2+p1\[CenterDot]p2)+k1\[CenterDot]s (k2\[CenterDot]p1+k2\[CenterDot]p2) (m^2+p1\[CenterDot]p2)+p1\[CenterDot]s (k1\[CenterDot]p1 k2\[CenterDot]p2-m^2 k1\[CenterDot]k2)-p2\[CenterDot]s (k1\[CenterDot]k2 (m^2+p1\[CenterDot]p2)+k2\[CenterDot]p1 (k1\[CenterDot]p1-k1\[CenterDot]p2))+2 k1\[CenterDot]p2 k2\[CenterDot]s p1\[CenterDot]q+2 k1\[CenterDot]p1 k2\[CenterDot]s p2\[CenterDot]q-k1\[CenterDot]p2 k2\[CenterDot]p2 p1\[CenterDot]s-k1\[CenterDot]k2 p1\[CenterDot]p2 p1\[CenterDot]s)
*

*>
*

*>
*

*> So couldn't you please explain why the result is sensitive to mathematically equal transformations and how I can solve this problem?
*

*>
*

*> I've tried to calculate it in Mathematica 6 and 8 with various FeynCalc versions and the result was always the same.
*

*>
*

*> Best Regards,
*

*> Nikita Belyaev
*

*>
*

**Next message:**Nikita Belyaev: "Re: Problem with the imaginary parts of the traces"**Previous message:**Nikita Belyaev: "Problem with the imaginary parts of the traces"**In reply to:**Nikita Belyaev: "Problem with the imaginary parts of the traces"**Next in thread:**Nikita Belyaev: "Re: Problem with the imaginary parts of the traces"**Messages sorted by:**[ date ] [ thread ] [ subject ] [ author ]**Mail actions:**[ respond to this message ] [ mail a new topic ]

*
This archive was generated by hypermail 2b29
: 10/23/18-01:40:01 AM Z CEST
*