Name: Rolf Mertig (email_not_shown)
Date: 11/15/11-11:55:16 PM Z


(* Using FeynCalc 8.0.3 with Mathematica 8 *)
(* the program below should print:

ans = (4*C*(FV[k, mu]*FV[k, nu] - MT[mu, nu]*SP[k, k])*(6*m^2 - 6*A0[m^2] - SP[k, k] + 3*B0[SP[k, k], m^2, m^2]*(2*m^2 + SP[k, k])))/(9*SP[k, k])

and

res3 = (2*C*(-(FV[k, mu]*FV[k, nu]) + MT[mu, nu]*SP[k, k])*(2*(-2 + D)*A0[m^2] - B0[SP[k, k], m^2, m^2]*(4*m^2 + (-2 + D)*SP[k, k])))/((-1 + D)*SP[k, k])

*)

Needs["HighEnergyPhysics`FeynCalc`"]
dm = GAD; ds = GS; mt = MT; fv = FV;
(*Now write the numerator of the Feynman diagram.We define the \
constant C=alpha/(4 pi)*)
num = -C Tr[dm[mu].(ds[q] + m).dm[nu].(ds[q] + ds[k] + m)] ;
(* By default FeynCalc to evaluates the integral in D dimensions *)
(* By default it also takes the limit D -> 4 *)
$LimitTo4 = True;

(*Define the amplitude*)
amp = num*FAD[{q, m}, {q + k, m}];
(*Calculate the result*)
res = (-I/Pi^2) OneLoop[q, amp] // PaVeReduce;
ans = Simplify[res // FCE];
Print["ans = ", ans // InputForm];
(* this is more general (no limit is taken): *)
res2 = OneLoopSimplify[amp, q] // Factor1
$LimitTo4 = False;
res3 = (-I/Pi^2) OneLoop[q, res2] // FCE // Simplify
Print["res3 = ", res3 // InputForm]



This archive was generated by hypermail 2b29 : 10/23/17-12:20:02 AM Z CEST